[ Retour aux Travaux Dirigés de SAS ]

/* Statistiques avec SAS, Preparation du TD 7 */
/* Jean-Sebastien Roy (js@jeannot.org), 2001 */

%let chemin=//diamant/Data Mi2/sas/stats;
libname tables "&chemin/tables";

proc import datafile="&chemin/infiles/commlimi.txt" out=commlimi
  dbms=tab replace;
run;

data commlimi;
  length dc $ 5;
  set commlimi(rename=(dc=dcn));
  dc=dcn;
  drop dcn;
run;

data tables.commlimi;
  set commlimi;
  where substr(dc,1,2) ne '75';

  array v{*} h00--h95 f00--f95;
  array w{20} hf00 hf05 hf10 hf15 hf20 hf25 hf30 hf35 hf40 hf45 hf50
  hf55 hf60 hf65 hf70 hf75 hf80 hf85 hf90 hf95;
  do _i_=1 to 20;
      w{_i_}=v{_i_}+v{_i_+20};
  end;
  cs1=cs11+cs12+cs13;
  cs2=cs21+cs22+cs23;
  cs3=sum(of cs31--cs38);
  cs4=sum(of cs42--cs48);
  cs5=sum(of cs52--cs56);
  cs6=sum(of cs62--cs69);
  cs7=sum(of cs71--cs78);
  cs8=sum(of cs81--cs86);
  regno11=sum(of r21--r94);
  franc=fr_nais+fr_acqui;
  euro=alle+belg+espa+ital+port+polo+youg+eur_est+autr_eur;
  maghreb=alge+maro+tuni;
  afriq=af_noi+aut_af;
  world=sovi+amer+calavi+liban+turc+aut_asie+nat_ocea;
  noeuro=world+afriq+maghreb;
  nofranc=noeuro+euro;
  iber=espa+port;
  jeunes=sum(of hf00--hf20);
  adultes=sum(of hf25--hf55);
  agees=sum(of hf60--hf95);
  hommes=sum(of h00--h95);
  femmes=sum(of f00--f95);
  pop=hommes+femmes;
  drop _i_;
run;